Исправление поврежденных файлов mbox с помощью sed/awk

Каждый раз, когда вы используете конструкции sed, отличные от s, g и p (с -n), вы используете неправильный инструмент. Если по какой-то причине вы не можете использовать formail, просто используйте awk:

$ awk '/^From/ && p{print ""} {p=NF; print}' file
...
Text of mail 1
... bla....
To unsubscribe, visit https:...

From fetchmail Fri Nov  8 18:35:54 CET 2002          ## ^missing empty line above
...
Text of mail 2
...

Это будет работать с использованием любого awk на любом компьютере UNIX, и он просто читает по одной строке за раз, поэтому он будет работать независимо от того, насколько велики ваши входные файлы.

который соответствует только последнему вхождению шаблона!?

Да. Regex жадный. .* соответствует всем, затем, после того, как все соответствует, сопоставляется последний одиночный \nFrom. Сопоставьте все, кроме новой строки, чтобы соответствовать одной строке.

sed -z -E 's/(\n[^\n]+\n)(From )/\1\n\2/g'

Если вы не хотите читать весь файл в память, вы должны прочитать как минимум две строки в памяти. Ниже я помещаю предыдущую строку в область хранения - добавляю текущую строку с предыдущей строкой в ​​каждую прочитанную строку, чтобы проверить условие. После проверки печатается предыдущая строка.

sed -n -E '
      # Hold first line.
      1{h;b}
      # Append the line to hold space and switch hold space with pattern space
      # so that we have previous\ncurrent lines in pattern space.
      H;x
      # If we have From prepended by anything in previous line, add a newline
      /.+\nFrom /s/\n/\n\n/
      # Remove current line
      s/\n[^\n]*$//
      # Print previous line. Maybe with extra newline.
      p
      # If its last line, also print the holded last line
      ${x;p}
'

и однострочник:

sed -nE '1{h;b};H;x;/.+\nFrom /s/\n/\n\n/;s/\n[^\n]*$//p;${x;p}'