Значение поля по умолчанию из запроса в MS Access

Я не уверен, что понял проблему, но я думаю, что вы просите вставить значение в поле, полученное из другой таблицы, на основе некоторой информации времени выполнения (например, имени пользователя). В этом случае вы можете использовать функцию поиска домена, DLookup(), и передать ей имя поля, которое вы хотите вернуть, имя таблицы или запроса, из которого вы его ищете, и критерии для ограничение результата одной строкой (что, как я предполагаю, будет зависеть от значений, которые вы можете собрать во время выполнения). Эта формула DLookup() может быть установлена ​​на постоянной основе в качестве значения по умолчанию в элементе управления формы и не приведет к загрязнению формы до того, как вы создадите реальную запись.

Конечно, я мог совершенно неверно истолковать то, что вы пытаетесь сделать, поэтому это может не сработать, но вы, похоже, хотели найти что-то в наборе записей и использовать результат в качестве значения для новых записей, а DLookup() позволяют вам сделать это вообще без какого-либо кодирования (а также с тем преимуществом, что вы не загрязняете запись преждевременно).

Я не знаю, как вы определяете, кто является текущим пользователем, но я предполагаю, что это то, что вы можете вызвать программно. Для простоты я буду использовать в этом примере встроенный в Access метод CurrentUser. (Требуется безопасность на уровне пользователя, в противном случае по умолчанию используется «Администратор».)

Создайте общедоступную функцию в модуле VBA, чтобы вернуть значение по умолчанию для текущего пользователя:

Public Function InsertDefaultSomeID() As String

InsertDefaultSomeID = DLookup("DefaultSomeID", "tblUserPref", _
                              "UserID='" & CurrentUser & "'")

End Function

В tblUserPref вам нужно поле [UserID] и поле [DefaultSomeID]. Определите значение по умолчанию для текущего пользователя.

Затем в форме, привязанной к tblMyTable, откройте Свойства для поля [SomeID] и установите для свойства Значение по умолчанию значение:

=InsertDefaultSomeID()

Сохраните форму, войдите в систему как пользователь с известным значением по умолчанию и попробуйте вставить новую запись. Ваше значение по умолчанию должно быть автоматически заполнено.

Вероятно, вы захотите поместить этот код в событие «Перед вставкой» для самой формы (ни одного из объектов в форме).

Исправление: на самом деле это не сработает, пока ваш пользователь не начнет вводить данные, поэтому вам просто нужно убедиться, что поля, для которых вы хотите иметь значения по умолчанию, идут после первого поля ввода данных.

Вы также можете проверить наличие новой записи в событии «Текущие».

Private Sub Form_Current()
    If Me.NewRecord Then
        Me.f2 = "humbug"
    End If
End Sub

Недостатком этого является то, что новая запись создается/помечается как грязная сразу после ее ввода. Таким образом, если вы бездумно пройдетесь по записям, вы можете в конечном итоге запустить конец и создать несколько дополнительных записей только с данными по умолчанию, поэтому вам придется что-то делать, чтобы отловить такое условие (например, обязательное поле, и т.д.)

Ты прав. Вы не можете установить для свойства значения по умолчанию элемента управления значение, неизвестное во время компиляции. Это значение будет определено во время выполнения. Таким образом, решение состоит в том, чтобы установить свойство значения элемента управления, а не свойство значения по умолчанию, во время текущего события формы. Обратите внимание, что getUserID() — это общедоступная функция, используемая для определения пользователя.

Private Sub Form_Current()

    On Error GoTo Proc_Err

    Dim rs As DAO.Recordset
    Dim fOpenedRS As Boolean

    If Me.NewRecord = True Then
        Set rs = CurrentDb.OpenRecordset("SELECT DefaultSomeID " _
        & "FROM tblUserPref WHERE UserID = " & getUserID())
        fOpenedRS = True
        rs.MoveFirst
        Me!txtPref.Value = rs!DefaultSomeID
    End If

Proc_Exit:
    If fOpenedRS = True Then
        rs.Close
    End If

    Set rs = Nothing

    Exit Sub

Proc_Err:
    MsgBox Err.Number & vbCrLf & Err.Description
    Err.Clear
    Resume Proc_Exit
End Sub

Он предложил альтернативный подход. Вместо того, чтобы явно ВСТАВЛЯТЬ значение по умолчанию, когда пользователь не указал явное значение, вместо этого оставьте это значение отсутствующим (я, вероятно, смоделировал бы это в специальной таблице и смоделировал бы отсутствующее значение, ну, не ВСТАВЛЯЯ строку, но я знаю многие люди не возражают против того, чтобы в их таблицах было много столбцов, допускающих значение NULL). Затем вы можете заменить отсутствующее значение в запросе. Это может быть или не быть действительным в вашем приложении, поскольку я говорю, что это просто еще один подход к обработке отсутствующих данных :)